Using "Send Partial" with WebSTAR 4 and Applescript CGIs

If you want to send responses from your Applescript CGIs in pieces (eg. if you are doing some time consuming processing and want to let the client know that the script has not stalled), here is an example script. Click, copy, and paste into your favorite script editor. As with all Applescript CGIs, save as an applet and check [Keep Open] and [Never Show Startup Screen].

property pageTitle : "Example Send Partial"

property crlf : (ASCII character 13) & (ASCII character 10)
property http_10_header : "HTTP/1.0 200 OK" & crlf & "Server: WebSTAR" & crlf & 
"MIME-Version: 1.0" & crlf & "Content-type: text/html" & crlf & crlf
property hht : "<ht" & "ml><he" & "ad><ti" & "tle>"
property thb : "</ti" & "tle></he" & "ad><bo" & "dy>"
property pressback : "Please press your browser's [Back] button and try again."
property br : " "
property rtn : return
property brr : br & rtn
property br2 : " "
property br2r : " " & rtn
property hr : "<hr>"
property hrr : "<hr>" & rtn
property bhr : "</bo" & "dy></ht" & "ml>" & return
property lastused : 0
property minutesToLive : 60

on run
	set lastused to 0
end run

on idle
	try
		set lastused to lastused + 1
		if lastused is less than minutesToLive then
			return 60
		else
			my resetVars()
			tell me to quit
		end if
	on error --
	end try
	set lastused to 0
	return 60
end idle

on resetVars()
	set lastused to 0
end resetVars

on handle CGI request URL_path ¬
	searching for searching_for ¬
	with posted data posted_data ¬
	of content type content_type ¬
	using access method access_method ¬
	from address client_address ¬
	from user userName ¬
	using password password ¬
	with user info user_info ¬
	from server server_name ¬
	via port server_port ¬
	executing by script_name ¬
	referred by referred_by ¬
	from browser browser_name ¬
	using action action_used ¬
	of action type action_type ¬
	from client IP address client_IP_address ¬
	with full request full_request ¬
	with connection ID connection_ID
	
	try
		my DoSendData(connection_ID, true, (http_10_header & hht & 
pageTitle & thb & "This is a test; please wait." & br2r))
		delay 3
		my DoSendData(connection_ID, true, "This is more of a test; 
please continue waiting." & br2r)
		delay 3
		my DoSendData(connection_ID, false, "Done. Use your browser's 
back button to return to where you were." & bhr)
		-- no need for a return!
	on error errmsg
		return (http_10_header & hht & "An Error Occurred" & thb & "An 
error occurred." & br2r & errmsg & br2r & pressback & bhr) as string
	end try
end handle CGI request

on DoSendData(connectionID, moreToSend, theData)
	tell application "WebSTAR 4.3"
		send partial theData connection connectionID more moreToSend
	end tell
end DoSendData

The meat of the script is as follows:

on DoSendData(connectionID, moreToSend, theData)
	tell application "WebSTAR 4.3"
		send partial theData connection connectionID more moreToSend
	end tell
end DoSendData

You must, as always, return a full http response header. There appears to be no need for a return command.

You will need to use your browser's [Back] button to return here.

My thanks to Wayne Walrath, and the WebSTAR-DEV list, for helping me finally figure this out.