LANbuddy(TM) - Control Your Networked Macs

Note: LANbuddy^TM was born as FinderFriend, but I quickly discovered that there were too many trademark issues. I have been unable to find any reference whatsoever anywhere on the Internet to "LANbuddy" and am hereby laying exclusive and perpetual claim to the term.

The LinkedResources Applescript Factory

LANbuddy™ - Control Your Networked Macs

These two Applescripts allow you to do the following with other Macs running MacOS 8 or 9 on your AppleTalk network:

Quit and restart the Finder
View active and prior processes (visible and background)
Quit and restart programs
Share your browser windows
Sign off America Online
Reboot them

Warning! This program carries security risks! If others have write access to your System Folder, serious mischief can be perpetrated with these scripts (or in many ways). You have been warned.

These scripts are free and open source but not public domain. Feel free to modify them for your own use, but do not further distribute modified copies. Please send your useful hacks/bug fixes to me using the email link below. Thanks!

Here is the script of LANbuddy™. Use Script Editor to save it as an app (never show startup screen, stay open) with the name "lanbuddy" (all lower case) or it won't work.

property pastProcs : {}

on run
	try
		tell application "File Sharing"
			activate
			if program linking is false then
				set program linking to true
			end if
			quit
		end tell
		tell application "Finder"
			activate
			set visible of me to false
		end tell
	on error
	end try
end run

on quitFinder()
	try
		tell application "Finder" to quit
	on error
	end try
end quitFinder

on startFinder()
	try
		tell application "Finder" to activate
	on error
	end try
end startFinder

on restartMachine()
	try
		tell application "Finder" to restart
	on error
	end try
end restartMachine

on getProcesses()
	try
		tell application "Finder"
			-- activate
			set currProcs to processes
			return my returnProcs(currProcs)
		end tell
	on error
		return ("Unable to get Processes" & return)
	end try
end getProcesses

on getVisibleProcesses()
	try
		tell application "Finder"
			--activate
			set currProcs to processes whose visible is true
			return my returnProcs(currProcs)
		end tell
	on error
		return ("Unable to get Processes" & return)
	end try
end getVisibleProcesses

on getBackgroundProcesses()
	try
		tell application "Finder"
			--activate
			set currProcs to processes whose visible is false
			return my returnProcs(currProcs)
		end tell
	on error
		return ("Unable to get Processes" & return)
	end try
end getBackgroundProcesses

on returnProcs(currProcs)
	set currProcsList to {}
	repeat with thisproc in currProcs
		set currProcsList to currProcsList & (thisproc as string)
	end repeat
	return currProcsList
end returnProcs

on quitProc(theProc)
	try
		set theProc to (theProc as string)
		tell application theProc to quit
		if theProc is not in pastProcs then
			set pastProcs to pastProcs & theProc
		end if
	on error
		activate me
		display dialog ("Unable to quit " & theProc) buttons {"Oh Well"} 
giving up after 2
	end try
end quitProc

on startProc(theProc)
	activate me
	try
		set theProc to (theProc as string)
		if theProc is not in pastProcs then
			tell application "Finder"
				set recentAppsFolder to ((path to apple menu as 
string) & "Recent Applications") as string
				set recentApps to files in folder recentAppsFolder
				repeat with i in recentApps
					set i2 to (name of i as string)
					if (i2 as string) is equal to (theProc as 
string) then
						open file (a reference to (i as string))
					end if
				end repeat
			end tell
		else
			tell application theProc to activate
		end if
	on error
		activate me
		display dialog ("Unable to start " & theProc) buttons {"Oh Well"} 
giving up after 2
	end try
end startProc

on getPastProcs()
	return pastProcs
end getPastProcs

on getRecentProcs()
	tell application "Finder"
		set recentAppsFolder to ((path to apple menu as string) & "Recent 
Applications") as string
		set recentApps to files in folder recentAppsFolder
		set remoteProcs to {}
		repeat with i in recentApps
			set i to (name of i as string)
			set remoteProcs to remoteProcs & i
		end repeat
	end tell
	return remoteProcs
end getRecentProcs

-- You may need to locate your Navigator app at compile time. 
-- If you don't use Navigator, comment out this code
on shareURL(theURL)
	try
		tell application "Netscape Navigatorâ¢ 4.08"
			activate
			OpenURL theURL toWindow 0
		end tell
	on error
		return "failure"
	end try
	return "success"
end shareURL

on giveURL()
	tell application "Netscape Navigatorâ¢ 4.08" to set URL2share to item 1 
of (get window info item 1 of (list windows))
	return URL2share
end giveURL

on closeTopWindow()
	try
		tell application "Netscape Navigatorâ¢ 4.08"
			set winlist to list windows
			if winlist is not equal to {} then
				close window 1
			end if
		end tell
	on error
		return "failure"
	end try
	return "success"
end closeTopWindow

on signOffAOL()
	-- You may need to locate your AOL app at compile time. 
	-- If you don't use AOL, comment out this code
	try
		tell application "America Online 4.0"
			Sign Off
		end tell
	on error
	end try
end signOffAOL

Here's what to do to enable LANbuddy™:

Put lanbuddy, or any alias to it, in the "Startup Items" folder of the System Folder of the Macs you wish to control.
Reboot the Macs.
Run the controller script/app (LANboss) as needed on your own machine to remotely control the other Macs.

Here is the script of LANboss™. Paste it into Script Editor and save it as an app (DO NOT check stay open). Put aliases in your Apple Menu and/or your Launcher. You will need to change the properties to match the names of your machines. One name can be the name of your own machine, if you like, but be sure to run lanbuddy on your machine too!

property remoteMachine1 : "iMacRevB"
property remoteMachine2 : "PowerBook G3"
property remoteMachine3 : "PowerMac 7200"
property remoteMachines : {remoteMachine1, remoteMachine2, remoteMachine3}
property firstChoices : {"Manage Processes", "Quit Finder", "Start Finder", 
"Restart Machine", "Share my browser's URL", "Show its browser's URL", "Close top 
browser window", "Sign off AOL"}

global remoteMachine
set whatRemote to "What remote machine do you want to control?"
set remoteMachine to (choose from list remoteMachines with prompt whatRemote 
default items (remoteMachine1 as list)) as string
set firstPrompt to ("What do you want to do with the machine " & remoteMachine & 
"?") as string
set remoteChoice to (choose from list firstChoices with prompt firstPrompt 
default items {"Manage Processes"}) as string
-- "login as" is one of the GTQ Scripting Additions which is found at
-- http://www.scriptweb.com/osaxen/gtq_scripting_library.html
login as "Jeffrey W Baumann" password "youwish"
if remoteChoice is equal to "Quit Finder" then my quitFinder()
if remoteChoice is equal to "Start Finder" then my startFinder()

if remoteChoice is equal to "Manage Processes" then my showProcesses()

if remoteChoice is equal to "Restart Machine" then
	try
		tell application "lanbuddy" of machine remoteMachine
			restartMachine()
		end tell
	on error
		try
			tell application "Finder" of machine remoteMachine to restart
		on error
		end try
	end try
end if
if remoteChoice is equal to "Share my browser's URL" then
	tell application "Netscape Navigatorâ¢ 4.08" to set URL2share to item 1 
of (get window info item 1 of (list windows))
	tell application "lanbuddy" of machine remoteMachine to shareURL(URL2share)
end if
if remoteChoice is equal to "Show its browser's URL" then
	tell application "lanbuddy" of machine remoteMachine
		set theURL to giveURL()
	end tell
	tell application "Netscape Navigatorâ¢ 4.08"
		activate
		OpenURL theURL toWindow 0
	end tell
end if
if remoteChoice is equal to "Close top browser window" then
	tell application "lanbuddy" of machine remoteMachine
		set whatHappened to closeTopWindow()
	end tell
end if
if remoteChoice is equal to "Sign off AOL" then
	tell application "lanbuddy" of machine remoteMachine
		signOffAOL()
	end tell
end if

on quitFinder()
	try
		tell application "lanbuddy" of machine remoteMachine
			quitFinder()
		end tell
	on error
		display dialog "Error using lanbuddy to quit the " & 
remoteMachine & Â¬
			" Finder. Do a direct force quit?" buttons {"Force Quit", 
"Forget It"} default button 2 giving up after 30
		set quitChoice to button returned of result
		if quitChoice is equal to "Force Quit" then
			try
				tell application "Finder" of machine 
remoteMachine to quit
			on error
				display dialog "Couldn't quit Finder" buttons 
{"Oh Well"} default button 1 giving up after 15
			end try
		end if
	end try
end quitFinder

on startFinder()
	try
		tell application "lanbuddy" of machine remoteMachine
			startFinder()
		end tell
	on error
		display dialog "Couldn't start Finder" buttons {"Oh Well"} 
default button 1 giving up after 15
	end try
end startFinder

on quitStartFinder()
	try
		display dialog ("Quit or start the " & remoteMachine & " 
Finder?") buttons {"Quit", "Start", "Cancel"} default button 3 giving up after 30
		set finderChoice to button returned of result
		if finderChoice is equal to "Quit" then
			try
				tell application "lanbuddy" of machine remoteMachine
					quitFinder()
				end tell
			on error
				display dialog "Error using lanbuddy to quit the 
" & remoteMachine & Â¬
					" Finder. Do a direct force quit?" 
buttons {"Force Quit", "Forget It"} default button 2 giving up after 30
				set quitChoice to button returned of result
				if quitChoice is equal to "Force Quit" then
					try
						tell application "Finder" of 
machine remoteMachine to quit
					on error
						display dialog "Couldn't quit 
Finder" buttons {"Oh Well"} default button 1 giving up after 15
					end try
				end if
			end try
		end if
		if finderChoice is equal to "Start" then
			try
				tell application "lanbuddy" of machine remoteMachine
					startFinder()
				end tell
			on error
				display dialog "Couldn't start Finder" buttons 
{"Oh Well"} default button 1 giving up after 15
			end try
		end if
	on error
	end try
end quitStartFinder

on showProcesses()
	set procChoiceList to {"Active", "Visible", "Background", "Inactive", 
"Stored", "Recent", "All Known"}
	set procBtns4active to {"Done", "Quit One"}
	set procBtns4inactive to {"Done", "Start One"}
	set procBtns4all to {"Done", "Quit One", "Start One"}
	set procBtns4none to {"Done"}
	set procChoice to choose from list procChoiceList with prompt ("What 
category of processes on " & remoteMachine & " would you like?") default items 
{"Visible"}
	set procChoice to procChoice as string
	set remoteProcs to {"User Cancelled"}
	set procWord to ""
	if procChoice is equal to "Active" then
		set procWord to "Active "
		tell application "lanbuddy" of machine remoteMachine
			startFinder()
			set remoteProcs to getProcesses()
		end tell
		set procBtns to procBtns4active
	end if
	if procChoice is equal to "Visible" then
		set procWord to "Active visible "
		tell application "lanbuddy" of machine remoteMachine
			startFinder()
			set remoteProcs to getVisibleProcesses()
		end tell
		set procBtns to procBtns4active
	end if
	if procChoice is equal to "Background" then
		set procWord to "Active background "
		tell application "lanbuddy" of machine remoteMachine
			startFinder()
			set remoteProcs to getBackgroundProcesses()
		end tell
		set procBtns to procBtns4active
	end if
	if procChoice is equal to "Inactive" then
		set procWord to "Inactive "
		tell application "lanbuddy" of machine remoteMachine
			startFinder()
			set pastProcs to getPastProcs()
			set recentProcs to getRecentProcs()
			set remoteProcs to getProcesses()
			set inactiveProcs to {}
			set pastProcsTemp to pastProcs & recentProcs
			set pastProcs to {}
			repeat with i in pastProcsTemp
				set i to i as string
				if i is not in pastProcs then
					set pastProcs to pastProcs & i
				end if
			end repeat
			repeat with i in pastProcs
				set i to i as string
				if i is not in remoteProcs then
					set inactiveProcs to inactiveProcs & i
				end if
			end repeat
			set remoteProcs to inactiveProcs
			if remoteProcs is not equal to {} then
				set procBtns to procBtns4inactive
			else
				set procBtns to procBtns4none
			end if
		end tell
	end if
	if procChoice is equal to "Stored" then
		set procWord to "Stored "
		tell application "lanbuddy" of machine remoteMachine
			startFinder()
			set remoteProcs to getPastProcs()
			if remoteProcs is not equal to {} then
				set procBtns to procBtns4inactive
			else
				set procBtns to procBtns4none
			end if
		end tell
	end if
	if procChoice is equal to "Recent" then
		set procWord to "Recent "
		tell application "lanbuddy" of machine remoteMachine
			startFinder()
			set remoteProcs to getRecentProcs()
			if remoteProcs is not equal to {} then
				set procBtns to procBtns4inactive
			else
				set procBtns to procBtns4none
			end if
		end tell
	end if
	if procChoice is equal to "All Known" then
		set procWord to "All known "
		tell application "lanbuddy" of machine remoteMachine
			startFinder()
			set pastProcs to getPastProcs()
			set recentProcs to getRecentProcs()
			set activeProcs to getProcesses()
			set rP to activeProcs & recentProcs & pastProcs
			set remoteProcs to {}
			repeat with i in rP
				set i to i as string
				if i is not in remoteProcs then
					set remoteProcs to remoteProcs & i
				end if
			end repeat
			set procBtns to procBtns4all
		end tell
	end if
	set remoteProcsString to ""
	if class of remoteProcs is list then -- maintains compatability with 
prior lanbuddys
		repeat with anyProc in remoteProcs
			set remoteProcsString to remoteProcsString & (anyProc as 
string) & return
		end repeat
	else
		set remoteProcsString to remoteProcs
	end if
	tell application "Finder"
		activate
		set headerText to procWord & "processes on " & remoteMachine & 
return & return
		-- "Active " & 
		set trailerText to return & "Now what?"
		set remoteProcs3 to headerText & remoteProcsString & trailerText
		set the clipboard to remoteProcsString
		display dialog remoteProcs3 buttons procBtns default button 1 
giving up after 30
		set btn to button returned of result
	end tell
	if btn is equal to "Quit One" then
		activate me
		set proc2quit to choose from list remoteProcs with prompt "Quit 
which app?" OK button name "Quit Process" cancel button name "Let them run"
		repeat while proc2quit is not equal to false
			tell application "lanbuddy" of machine remoteMachine
				quitProc(proc2quit)
			end tell
			set remoteProcs2 to {}
			repeat with anyProc in remoteProcs
				if (anyProc as string) is not equal to (proc2quit 
as string) then
					set remoteProcs2 to remoteProcs2 & anyProc
				end if
			end repeat
			set remoteProcs to remoteProcs2
			activate me
			if remoteProcs is not equal to {} then
				set proc2quit to choose from list remoteProcs 
with prompt "Quit which app?" OK button name "Quit Process" cancel button name 
"That's enough"
			else
				set proc2quit to false
				beep 1
			end if
		end repeat
	end if
	if btn is equal to "Start One" then
		activate me
		if remoteProcs is not equal to {} then
			set proc2start to choose from list remoteProcs with 
prompt "Start which app?" OK button name "Start Process" cancel button name "Let 
them sleep"
		else
			set proc2start to false
			beep 1
		end if
		repeat while proc2start is not equal to false
			tell application "lanbuddy" of machine remoteMachine
				startProc(proc2start)
			end tell
			set remoteProcs2 to {}
			repeat with anyProc in remoteProcs
				if (anyProc as string) is not equal to 
(proc2start as string) then
					set remoteProcs2 to remoteProcs2 & anyProc
				end if
			end repeat
			set remoteProcs to remoteProcs2
			activate me
			if remoteProcs is not equal to {} then
				set proc2start to choose from list remoteProcs 
with prompt "Start which app?" OK button name "Start Process" cancel button name 
"That's enough"
			else
				set proc2start to false
				beep 1
			end if
		end repeat
	end if
	activate me
end showProcesses