Grabbing man pages in MacOS X

[Home] [Blogs] [XiTouch] [Tools] [Services] [Teach] [Mac] [My Blog] [Contact]

Grabbing man pages in MacOS X

MacOS X hs been around for many years. You know a little Applescript. You fancy yourself a skilled mousesmith. But you still haven't jumped feet first into the Unix command line. It's so intimidating - so many obscure little commands! How can you possibly learn them all?

Why, with grabMan™, of course!

GrabMan™ is a short Applescript applet which lets you view a list of the commands which are available thru the Unix command line (and therefore thru "do shell script" in MacOSX Applescript), select one, and have the man page (manual, synopsis, instructions) saved to disk and opened using BBEdit ~~or TextWrangler (TextWrangler is the long awaited replacement to BBEdit; both are~~ from BareBones). If there is a specific man page you want, you can enter it directly without choosing from a list.

1) In MacOSX, open Script Editor and copy the script below into it. Compile it and save it as an applet (Stay Open - No; Never Show Startup Screen - Yes) with the name "grabMan".

property shortname : ""
property texteditor : ""

property pathsToShellCommands : {"/usr/bin", "/usr/sbin", "/sbin", "/bin"}
-- , "/System/Library/Frameworks/JavaVM.framework/Versions/1.3.1/Home/bin"

set shortname to do shell script "whoami"

if texteditor is equal to "" then
	display dialog "BBEdit or TextWrangler?" buttons {"BBEdit", "TextWrangler", "Cancel"}
	set x to button returned of the result
	if x is equal to "BBEdit" then
		set texteditor to "R*ch"
	else
		set texteditor to "!Rch"
	end if
end if

set ddText to "What shell command do you want to grab a man page for?"
set listButton to "Show Me A List"
set ddButtons to {listButton, "Cancel", "OK"}
set ddResult to display dialog ddText default answer "" buttons ddButtons
set btnChoice to button returned of ddResult
if btnChoice is equal to "Cancel" then tell me to quit

if btnChoice is equal to listButton then
	set shellCommands to ""
	set dashes to "----"
	repeat with aPath in pathsToShellCommands
		set shellscript to "ls " & aPath
		set moreShellCommands to do shell script shellscript
		set shellCommands to shellCommands & dashes & aPath & dashes & return & moreShellCommands & return
	end repeat
	set shellCommands to my powerSplit(shellCommands, {return})
	set shellCommand to (choose from list shellCommands) as string
else
	set shellCommand to text returned of ddResult
end if

-- make MacOS paths
set rootDrive to ":" as alias as string -- in OSX, this gives the hard drive name + colon
set subPath to ":" & character 1 of shellCommand & ":" & character 2 of shellCommand
set manPagesFolder to (rootDrive & "Users:" & shortname & ":Documents:manpages" & subPath)
set manFile to (manPagesFolder & ":" & shellCommand)

-- make Unixy path
set manPagesFolder2 to POSIX path of manPagesFolder
set manFile2 to POSIX path of manFile

-- make sure the destination folder exists
set mkdir to ("mkdir -p -m 770 " & manPagesFolder2)
do shell script mkdir

-- use the command line to clean the text and write it to file
set mancol to ("man " & shellCommand & "  | col -b > " & manFile2)
do shell script mancol

tell application "Finder"
	set creator type of file manFile to texteditor -- BBEdit or TextWrangler
	open file manFile -- using application file (rootDrive & textEditorPath)
end tell

-- from my library; is there  a Unix way to do this? Only the real geeks know for sure

on powerSplit(src, delimList)
	-- set newDelim to (item 1 of delimList) as string
	set newDelim to {(item 1 of delimList) as string}
	if length of delimList is equal to 1 then
		set srcAsList to {}
		try
			set oldDelims to AppleScript's text item delimiters
			set AppleScript's text item delimiters to newDelim
			set srcAsList to (text items of src) as list
			set AppleScript's text item delimiters to oldDelims
		on error
			try
				set AppleScript's text item delimiters to oldDelims
			on error
				set AppleScript's text item delimiters to {""}
			end try
		end try
		return srcAsList
	else
		set linesAsList to {}
		set srcAsList to my powerSplit(src, newDelim)
		repeat with aLine in srcAsList
			set aLineAsList to my powerSplit(aLine, (rest of delimList))
			copy aLineAsList to end of linesAsList
		end repeat
		return linesAsList
	end if
end powerSplit

2) Once you've saved the applet as above, drag the grabMan application icon up to a Finder window toolbar (Jaquar, as shown), or the navigation pane (Panther, left side of Finder windows).

3) Now click on the toolbar icon. The rest should be self-explanatory. Analyzing the script for learning purposes is left as an exercise for the user.

Another man page reference can be found here, but it may not be directly applicable to MacOSX.

jwbaumann(shift-2)linkedresources(dot)com

[Home] [Blogs] [XiTouch] [Tools] [Services] [Teach] [Mac] [My Blog] [Contact]